Einstellungen sichern



  • Gibts die Möglichkeit alle Einstellungen die man im Laufe der Zeit in Vivaldi gemacht hat zu sixhern,
    oder ein Backup zu erstellen um diese dann schnell nach einer Neuinstallation wieder einzuspielen ?



  • @rerosbk Aktuell ist das noch nicht vorgesehen, ist aber in Arbeit.

    Hier hat ein Nutzer ein Tool dafür erstellt, welches ich aber nicht getestet habe, also keine Gewähr, dass das funktioniert und / oder sauber ist.

    Ein anderer Weg, das quasi "zu Fuß" zu machen ist folgender:

    • Menü-> Hilfe -> Über oder gib in die Urlzeile vivaldi://about/ ein
    • Dort findest du einen Eintrag Profil Pfad / Profile Path
    • Kopiere oder merke dir diesen Pfad und rufe ihn im Explorer auf
    • Der Default-Ordner enthält nahezu! dein komplettes Profil:
      • Bookmarks
      • Notes
      • Sessions
      • Logindaten (sind verschlüsselt und funktionieren deswegen ausschließlich auf diesem einen PC von dem das Profil stammt - also vorsicht mit Passwörtern die du eventuell vergessen hast, kümmere dich vorher darum wenn du das Profil zu einem anderen PC übertragen willst)
      • Einstellungen von Vivaldi selber
      • Autofill Daten
      • Offene Tabs Tabs die noch offen waren als du den Browser das letzte mal geschlossen hast
      • Thumbnails
      • Browserverlauf
      • Extensions hier bitte auch vorsicht, da dies wohl nicht für alle Extensions gilt bzw. diese nur auf diesem einen PC funktionieren
    • Den Default Ordner kopieren und dorthin speichern wo du ihn sichern möchtest
    • Nach einer Neuinstallation austauschen

    Das ganze lässt sich nochmal etwas ausführlicher hier nachlesen, da ich die Infos mehr order weniger nur von da übernommen habe



  • Ich habe mir vor einiger Zeit dieses CMD Script erstellt. Wenn man gepackte Backups erstellen will sollte 7zip in seinem default Verzeichnis installiert sein, ansonsten gibt es keine Abhängigkeiten. Einfach Code zwischen den ... kopieren und als Backup.cmd speichern und den Anweisungen hinter REM folgen (nicht wundern, ich kommentiere immer Englisch, wenn ich scribbele):

    @echo off
    REM For stand alone installs, that contain everything in one folder:
    REM Throw this file in the directory that contains your "user data" directory.
    REM
    REM For regular installs in the default location:
    REM Place this file in a directory where you have write access.
    REM
    REM The backups will be created in the folder containing this CMD file.
    REM You need 7zip and it should be installed in the default location.
    :testifrunning
    tasklist /nh /fi "imagename eq vivaldi.exe" | find /i "vivaldi.exe" >nul && (
    goto running
    ) || (
    goto question
    )
    
    :running
    echo.
    echo An instance of Vivaldi is running! 
    echo Please close all instances of Vivaldi and try again.
    echo.
    CHOICE /T 10 /C RE /M "[R]etry (default) - e[X]it" /D R
    IF ERRORLEVEL 2 exit
    IF ERRORLEVEL 1 GOTO testifrunning
    
    :question
    echo.
    CHOICE /T 10 /C BE /M "[B]ackup (default) - e[X]it" /D B
    IF ERRORLEVEL 2 exit
    IF ERRORLEVEL 1 GOTO backup
    
    :backup
    REM Create a list of folders\ and files that should not be copied.
    REM You might want to REM the stuff you want to keep
    echo data_reduction_proxy_leveldb\ > excludelist.txt
    echo \Crashpad\ >> excludelist.txt
    echo \Cache\ >> excludelist.txt
    echo \GPUCache\ >> excludelist.txt
    echo \Pepper^ Data\ >> excludelist.txt
    echo \Media^ Cache\ >> excludelist.txt
    echo \ShaderCache\ >> excludelist.txt
    echo \JumpListIcons\ >> excludelist.txt
    echo \CertificateTransparency\ >> excludelist.txt
    echo \EVWhitelist\ >> excludelist.txt
    echo.
    IF EXIST "%cd%\User Data\" (
    set USERDATAFOLDER="%cd%\User Data"
    goto foundprofile
    )
    IF EXIST "%LOCALAPPDATA%\Vivaldi\User Data\" (
    set USERDATAFOLDER="%LOCALAPPDATA%\Vivaldi\User Data"
    goto foundprofile
    )
    echo No 'User Data' directory found.
    goto end
    
    :foundprofile
    set TEMPFOLDER="%cd%\Vivaldi-backup\User Data"
    echo Copying %USERDATAFOLDER% ...
    xcopy %USERDATAFOLDER% %TEMPFOLDER% /I /S /D /Q /G /EXCLUDE:excludelist.txt
    
    REM Removing the attributes or else some files can't be deleted
    attrib /D /S -R -H -S "%cd%\Vivaldi-backup\*"
    echo Deleting TMP files ...
    del /F /S /Q "%cd%\Vivaldi-backup\*.tmp" >nul
    
    echo Done.
    
    REM Prepare the timestamp
    REM If the date does not look right, you need to change this
    FOR /F "TOKENS=1,2,3 DELIMS=/. " %%a IN ('DATE /T') DO FOR /F "TOKENS=1-3 DELIMS=:., " %%E IN ("%TIME: =0%") DO SET TIMESTAMP=%%c-%%b-%%a_%%E%%F%%G
    
    
    REM There are different paths to the 7zip application. 
    REM This works for the default i386 or x64 install
    REM Adapt the paths, if necessary
    if exist "%programfiles%\7-Zip\7z.exe" (
    goto x64
    ) 
    if exist "%programfiles(x86)%\7-Zip\7z.exe" (
    goto x86
    ) else (
    echo could not find 7-zip in the standard directories.
    goto end
    )
    
    :x86
    echo Zipping files to %cd%\%TIMESTAMP%_vivaldi_backup.zip
    "%programfiles(x86)%\7-Zip\7z.exe" a "%cd%\%TIMESTAMP%_vivaldi_backup.zip" "%cd%\Vivaldi-backup\User Data" >nul
    IF ERRORLEVEL 1 goto ziperror
    goto success
    
    :x64
    echo Zipping files to %cd%\%TIMESTAMP%_vivaldi_backup.zip
    "%programfiles%\7-Zip\7z.exe" a "%cd%\%TIMESTAMP%_vivaldi_backup.zip" "%cd%\Vivaldi-backup\User Data" >nul
    IF ERRORLEVEL 1 goto ziperror
    goto success
    
    :ziperror
    echo.
    echo An error occurred while packing the file. 
    echo The archive (if any) might be corrupted.
    goto end
    
    :success
    echo.
    echo Files successfully zipped to %cd%\%TIMESTAMP%_vivaldi_backup.zip
    
    REM Cleaning up
    IF EXIST "%cd%\Vivaldi-backup\" (
    echo Deleting temporary Vivaldi-backup folder ...
    REM Some systems don't remove everything if the directory is not really empty
    del /F /S /Q "%cd%\Vivaldi-backup" >nul
    RD /S /Q "%cd%\Vivaldi-backup" > nul
    )
    del "%cd%\excludelist.txt" /Q
    goto end
    
    :end
    echo.
    echo Press any key to exit.
    pause>nul
    exit
    


  • Sehr schön, danke


Log in to reply
 

Looks like your connection to Vivaldi Forum was lost, please wait while we try to reconnect.